1. La partie 1, le code de la version 1, explique
   • Comment choisir un fichier en VB.
   • Comment créer les aperçus.
   • Comment implémenter les protocoles pour Internet.
2. La partie 2 explique comment mettre le programme en petite icône, et comment y attacher un menu.
3. La partie 3, le code de la version 2.2, explique comment avoir des informations sur un fichier et comment mettre un fichier dans la poubelle.
4. Cette dernière partie, le code de la version 3, explique comment afficher les clichés (ou slides) AutoCAD, y compris ceux qui sont dans des bibliothèques.
   Le code ci-dessous est à rajouter au code des versions 1, 2 et 2,2.

• Les fichiers .dwg (rien de changé).
• Les fichiers .sld : cliché simple.
• Les fichiers .slb : bibliothèque de clichés .

regsvr32 <c:\votre_Répertoire_ou_est_placé_l'OCX>\slide.ocx

• Affichage du contrôle cliche1 ou du contrôle DwgVignette1


• Affichage ou non de la liste de clichés en bibliothèque lstSld1


• Affichage d'un message différent.


• Appel de la fonction de lecture des noms de clichés si 'b' ou 'B'.


• Affichage du cliché ou de l'apperçu du dessin.

Public Sub filFich1_Click()
  lblMessage.Caption = " "
  Chemin = dirDisc1.Path
  If Right$(Chemin, 1) <> "\" Then
    Chemin = Chemin + "\"
  End If
  Fichier = filFich1.FileName
  FichVi$ = Chemin + filFich1.FileName
  FichInfo (FichVi$)
  strTaille = Str(FileLen(FichVi$))
  lblTaille.Caption = Format(strTaille, " ### ### ###") + " octets"
  If UCase(Right(FichVi$, 1)) = "B" Then
     BibCliche
     DwgVignette1.Visible = False
     Cliche1.Visible = True
     Cliche1.FileName = FichVi$ + "(" + lstSld1.List(lstSld1.ListIndex) + ")"
     lblMessage.Caption = "Cliché AutoCAD dans une bibliothèque"
  End If
  If UCase(Right(FichVi$, 1)) = "D" Then
     lstSld1.Visible = False
     DwgVignette1.Visible = False
     Cliche1.Visible = True
     Cliche1.FileName = FichVi$
     lblMessage.Caption = "Cliché AutoCAD indépendant"
  End If
  On Error GoTo Erreur1
  If UCase(Right(FichVi$, 1)) = "G" Then
     lstSld1.Visible = False
     DwgVignette1.Visible = True
     Cliche1.Visible = False
     DwgVignette1.DwgFileName = FichVi$
     lblMessage.Caption = "Cliquez sur l'image pour lancer le dessin"
     DwgVignette1.Refresh
  End If

  Exit Sub
Erreur1:
  DwgVignette1.Refresh
  lblMessage.Caption = "Ce fichier n'est pas au format R13 ou R14"
End Sub

• Ajout des deux dernières lignes pour ne pas afficher les contrôles pour les clichés.

Private Sub Form_Load()
  'Préparation de la variable IconeT
  IconeT.cbSize = Len(IconeT) 'Taille de l'icône en octet
  IconeT.hwnd = Me.hwnd       'Handle de ExplorAcad (pour qu'elle reçoive les messages
                              'envoyés lors d'un clic, double-clic...
  IconeT.uID = 1&             'Identificateur de l'icône
  IconeT.uFlags = Icone Or TIP Or MESSAGE
  IconeT.uCallbackMessage = MOUSEMOVE     'Renvoie les messages concernant l'action de la souris
  IconeT.hIcon = Form1.Icon               'Met en icône l'image qui est dans le contrôle "Image1"
  IconeT.szTip = "ExplorAcad" & Chr$(0)    'Texte de la bulle d'aide
  Me.Hide
  Shell_NotifyIcon AJOUT, IconeT
  lstSld1.Visible = False 			' << nouveau
  Cliche1.Visible = False			' << nouveau
End Sub

• Lecture du fichier bibliothèque en mode binary, octet par octet


• Les noms des clichés sont inscrits dans la 1ère ligne du fichier.


• Le premier nom commence au 33ème octet.


• Chaque définition de cliché se fait sur 36 octets


• On lit les 10 premiers caractères.


• Si le nom du cliché est AutoCAD Sl, la liste est terminée

Public Sub BibCliche()
   Dim strDef(0 To 200) As String
   Dim Octet As Byte
   Dim Caract As String
   Dim Chaine1 As String
   Dim NomCli(0 To 200) As String
   Dim X As Integer
   Dim Y As Integer
   Dim A As Integer
   Dim NumCli As Integer
   Dim Z As Integer

   ' On rend visible le contrôle de la liste des clichés 
   lstSld1.Visible = True
   lstSld1.Clear
   NumCli = 1

   Open FichVi$ For Binary As #1
   ' Lecture des noms de slide sur la première ligne
   For A = 0 To 10000 Step 36
     For X = A + 33 To A + 68
       Get #1, X, Octet
       Caract = Str$(Octet)
       Caract = Right(Str$(Octet), Len(Caract) - 1)
       Caract = Right("000000" + Caract, 4)
       strDef(NumCli) = strDef(NumCli) + Caract + " "
     Next X
     'exemple de résultat : 0067 0065 0051 0048 0055 0000 0000 0000  ... pour CA307
     'traduction du résultat précédent en chaîne
     For Y = 1 To 50 Step 5          ' 1O fois 4 octets + un espace
        ' s'il y a 4 zéros, cliché suivant
       If Mid(strDef(NumCli), Y, 4) = "0000" Then GoTo Suivant
       Chaine1 = Chr$(Val(Mid(strDef(NumCli), Y, 4)))
       NomCli(NumCli) = NomCli(NumCli) + Chaine1
       If NomCli(NumCli) = "AutoCAD Sl" Then GoTo FinListe
     Next Y
Suivant:
    NumCli = NumCli + 1
    Next A
FinListe:
    Close #1
    For Z = 1 To NumCli - 2
      lstSld1.AddItem NomCli(Z)
    Next Z
End Sub

• Action sur un élément de la liste des clichés de la bibliothèque.

Private Sub lstSld1_Click()
     Cliche1.FileName = FichVi$ + "(" + lstSld1.List(lstSld1.ListIndex) + ")"
End Sub

La partie 1 - Comment choisir un fichier en VB, comment créer les aperçus, comment implémenter les protocoles pour Internet.